# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit meson

DESCRIPTION="Plugin manager for app-text/lite-xl"
HOMEPAGE="https://github.com/lite-xl/lite-xl-plugin-manager"

if [[ ${PV} == 9999 ]]; then
	inherit git-r3
	EGIT_SUBMODULES=()
	EGIT_REPO_URI="https://github.com/lite-xl/lite-xl-plugin-manager.git"
else
	SRC_URI="https://github.com/lite-xl/lite-xl-plugin-manager/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
	KEYWORDS="~amd64"
fi

LICENSE="MIT"
SLOT="0"
IUSE="+lite-xl"

RDEPEND="
	sys-libs/zlib
	<net-libs/mbedtls-3
	dev-libs/libgit2
	dev-libs/libzip
	dev-lang/lua:5.4
"
DEPEND="${RDEPEND}"

src_prepare() {
	# pkgconfig fix
	sed -i -e "s/dependency('lua')/dependency('lua5.4')/" meson.build

	eapply_user
}

src_configure() {
	# disable self-upgrading (won't work when installed system-wide anyway)
	append-cppflags '-DLPM_DEFAULT_RELEASE=""'

	local emesonargs=(
		-Dstatic=true
	)
	meson_src_configure
}

src_install() {
	dobin "${BUILD_DIR}/lpm"

	if use lite-xl; then
		insinto /usr/share/lite-xl
		doins -r libraries plugins
	fi

	einstalldocs
}