# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit cmake

DESCRIPTION="Accurate Nintendo 64 Emulator, GUI frontend"
HOMEPAGE="https://simple64.github.io/"

if [[ ${PV} == 9999 ]] ; then
	inherit git-r3
	EGIT_REPO_URI="https://github.com/simple64/mupen64plus-gui.git"
else
	_git_commit="5e2995912bf712deac247b1cd7d768f6d7f0ceb3"
	SRC_URI="https://github.com/simple64/mupen64plus-gui/archive/${_git_commit}.tar.gz -> ${PN}-${_git_commit}.tar.gz"
	KEYWORDS="~amd64 ~x86"
fi

LICENSE="GPL-2 Apache-2.0 BSD-2 LGPL-2.1+ ZLIB BitstreamVera"
SLOT="0/${PV}"
IUSE="discord"

DEPEND="
	games-emulation/simple64-core:=
	dev-qt/qtbase:6=[widgets]
	dev-qt/qtwebsockets:6=
	discord? ( dev-libs/discord-game-sdk )
"
RDEPEND="${DEPEND}"

PATCHES=(
	"${FILESDIR}/fix-paths.patch"
)

src_prepare() {
	local commit="${_git_commit}"
	if [[ ${PV} == 9999 ]]; then
		commit="$(git rev-parse HEAD)"
	fi
	echo "#define GUI_VERSION \"${_git_commit}\"" >version.h
	sed -i 's|include_directories(../mupen64plus-core/src/api)|include_directories(/usr/include/mupen64plus)|' CMakeLists.txt
	cmake_src_prepare
}

src_configure() {
	local mycmakeargs=(
		-DCORE_LIBRARY_PATH="/usr/$(get_libdir)"
		-DPLUGIN_DIR_PATH="/usr/$(get_libdir)/mupen64plus"
	)
	cmake_src_configure
}

src_install() {
	dobin "${BUILD_DIR}/simple64-gui"
}