# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit meson

DESCRIPTION="Archlinux's binary package manager"
HOMEPAGE="https://archlinux.org/pacman/"

if [[ ${PV} == 9999 ]] ; then
	inherit git-r3
	EGIT_REPO_URI="https://gitlab.archlinux.org/pacman/pacman.git"
else
	SRC_URI="https://sources.archlinux.org/other/pacman/${P}.tar.xz"
	KEYWORDS="~amd64"
fi

LICENSE="GPL-2"
SLOT="0/13"

IUSE="curl debug doc +gpg test"

RDEPEND="
	curl? ( net-misc/curl )
	gpg? ( app-crypt/gpgme:= )
	dev-libs/openssl:0=
	app-arch/libarchive
"
DEPEND="
	${RDEPEND}
	test? (
		sys-apps/fakeroot
		sys-apps/fakechroot
	)
"
BDEPEND="
	app-text/asciidoc
	doc? ( app-text/doxygen )
"

RESTRICT="!test? ( test )"

src_configure() {
	local emesonargs=(
		--localstatedir=/var
		-D crypto=openssl
		-D doc=enabled
		$(meson_use debug)
		$(meson_feature curl)
		$(meson_feature doc doxygen)
		$(meson_feature gpg gpgme)
	)
	meson_src_configure
}

src_install() {
	meson_src_install

	# avoid creating stuff inside /var/cache/
	# see bug #633742 for more information
	rm -r "${D}"/var/cache/pacman
	rmdir "${D}"/var/cache
}

pkg_postinst() {
	einfo ""
	einfo "The default root dir was set to ${EPREFIX}/var/chroot/archlinux"
	einfo "to avoid breaking Gentoo systems due to oscitancy."
	einfo "If you prefer another directory, take a look at"
	einfo "pacman's parameter -r|--root)."
	einfo ""
	einfo "You will need to setup at least one mirror in /etc/pacman.d/mirrorlist."
	einfo "Please generate it manually according to the Archlinux documentation:"
	einfo "https://wiki.archlinux.org/index.php/Mirror"
	einfo ""
	einfo "The pacman-contrib scripts have been moved out of the main pacman"
	einfo "package and now have to be installed from app-misc/pacman-contrib."
	einfo ""
}