blob: 9cf971819d6c7e83738e4bf2d4a1aa08680ce5ef (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
|
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake xdg-utils
DESCRIPTION="RPG Maker 2000/2003 and EasyRPG games interpreter"
HOMEPAGE="https://easyrpg.org/"
if [[ ${PV} == 9999 ]]; then
inherit git-r3
EGIT_REPO_URI="https://github.com/EasyRPG/Player.git"
else
SRC_URI="https://github.com/EasyRPG/Player/archive/refs/tags/${PV}.tar.gz -> easyrpg-player-${PV}.tar.gz"
S="${WORKDIR}/Player-${PV}"
KEYWORDS="~amd64"
fi
LICENSE="GPL-3"
SLOT="0"
IUSE="
fluidsynth
+freetype
+json
libsamplerate
+midi
+mp3
opus
sdl3
+sndfile
+speexdsp
+vorbis
wildmidi
xmp
"
RDEPEND="
>=dev-games/liblcf-$(ver_cut 1-3)[ini]
>=dev-libs/libfmt-6:=
media-libs/libpng
x11-libs/pixman
fluidsynth? ( media-sound/fluidsynth:= )
freetype? (
media-libs/freetype:2
media-libs/harfbuzz:=
)
json? ( dev-cpp/nlohmann_json )
libsamplerate? ( media-libs/libsamplerate )
midi? ( media-libs/alsa-lib )
mp3? ( media-sound/mpg123-base )
opus? ( media-libs/opusfile )
!sdl3? ( >=media-libs/libsdl2-2.0.14[video] )
sdl3? ( media-libs/libsdl3 )
sndfile? ( media-libs/libsndfile )
speexdsp? ( media-libs/speexdsp )
vorbis? ( media-libs/libvorbis )
wildmidi? ( media-sound/wildmidi )
xmp? ( media-libs/libxmp )
"
DEPEND="${RDEPEND}"
src_configure() {
local mycmakeargs=(
-DPLAYER_ENABLE_DRWAV=OFF
-DPLAYER_ENABLE_TESTS=ON
-DPLAYER_TARGET_PLATFORM="$(usex sdl3 SDL3 SDL2)"
-DPLAYER_WITH_FLUIDSYNTH="$(usex fluidsynth)"
-DPLAYER_WITH_FREETYPE="$(usex freetype)"
-DPLAYER_WITH_HARFBUZZ="$(usex freetype)"
-DPLAYER_WITH_LIBSNDFILE="$(usex sndfile)"
-DPLAYER_WITH_MPG123="$(usex mp3)"
-DPLAYER_WITH_NATIVE_MIDI="$(usex midi)"
-DPLAYER_WITH_NLOHMANN_JSON="$(usex json)"
-DPLAYER_WITH_OGGVORBIS="$(usex vorbis)"
-DPLAYER_WITH_OPUS="$(usex opus)"
-DPLAYER_WITH_SAMPLERATE="$(usex libsamplerate)"
-DPLAYER_WITH_SPEEXDSP="$(usex speexdsp)"
-DPLAYER_WITH_WILDMIDI="$(usex wildmidi)"
-DPLAYER_WITH_XMP="$(usex xmp)"
)
cmake_src_configure
}
src_test() {
cmake_build check
}
pkg_postinst() {
xdg_desktop_database_update
}
|
