1 files changed, 85 insertions, 0 deletions
diff --git a/sys-apps/pacman/pacman-9999.ebuild b/sys-apps/pacman/pacman-9999.ebuild
new file mode 100644
index 0000000..e89b14c
--- /dev/null
+++ b/sys-apps/pacman/pacman-9999.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson
+
+DESCRIPTION="Archlinux's binary package manager"
+HOMEPAGE="https://archlinux.org/pacman/"
+
+if [[ ${PV} == 9999 ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.archlinux.org/pacman/pacman.git"
+else
+	SRC_URI="https://gitlab.archlinux.org/pacman/pacman/-/archive/v${PV}/pacman-v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+	S="${WORKDIR}/pacman-v${PV}"
+fi
+
+LICENSE="GPL-2"
+SLOT="0/13"
+
+IUSE="curl debug doc +gpg test"
+
+RDEPEND="
+	curl? ( >=net-misc/curl-7.55.0 )
+	gpg? ( >=app-crypt/gpgme-1.12.0:= )
+	dev-libs/openssl:0=
+	>=app-arch/libarchive-3.0.0
+	>=app-shells/bash-4.4
+"
+DEPEND="
+	${RDEPEND}
+	test? (
+		sys-apps/fakeroot
+		sys-apps/fakechroot
+	)
+"
+BDEPEND="
+	app-text/asciidoc
+	doc? ( app-text/doxygen )
+"
+
+RESTRICT="!test? ( test )"
+
+src_configure() {
+	local emesonargs=(
+		--localstatedir=/var
+		-Dcrypto=openssl
+		-Ddoc=enabled
+		# Help protect user from shooting their Gentoo installation
+		# in its foot.
+		-Droot-dir="${EPREFIX}/var/chroot/archlinux"
+		$(meson_use debug)
+		$(meson_feature curl)
+		$(meson_feature doc doxygen)
+		$(meson_feature gpg gpgme)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	# avoid creating stuff inside /var/cache/
+	# see bug #633742 for more information
+	rm -r "${D}"/var/cache/pacman
+	rmdir "${D}"/var/cache
+}
+
+pkg_postinst() {
+	einfo ""
+	einfo "The default root dir was set to ${EPREFIX}/var/chroot/archlinux"
+	einfo "to avoid breaking Gentoo systems due to oscitancy."
+	einfo "If you prefer another directory, take a look at"
+	einfo "pacman's parameter -r|--root)."
+	einfo ""
+	einfo "You will need to setup at least one mirror in /etc/pacman.d/mirrorlist."
+	einfo "Please generate it manually according to the Archlinux documentation:"
+	einfo "https://wiki.archlinux.org/index.php/Mirror"
+	einfo ""
+	einfo "The pacman-contrib scripts have been moved out of the main pacman"
+	einfo "package and now have to be installed from app-misc/pacman-contrib."
+	einfo ""
+}