summaryrefslogtreecommitdiffstats
path: root/build.gradle
blob: b4feed9798f06915d142356237fea87438bd66d2 (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
plugins {
	id 'fabric-loom' version '0.12-SNAPSHOT'
	id 'maven-publish'
	id "com.modrinth.minotaur" version "2.+"
	id "com.matthewprenger.cursegradle" version "1.+"
}

sourceCompatibility = JavaVersion.VERSION_17
targetCompatibility = JavaVersion.VERSION_17

archivesBaseName = project.archives_base_name
version = project.mod_version
group = project.maven_group

loom {
	accessWidenerPath = file("src/main/resources/nochatreports.accesswidener")
}

repositories {
	maven { url "https://maven.shedaniel.me/" }
	maven { url "https://maven.terraformersmc.com/releases/" }
	maven { url 'https://jitpack.io' }
}

dependencies {
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	mappings loom.officialMojangMappings()
	modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"
	modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"
	//modImplementation "com.terraformersmc:modmenu:${project.mod_menu_version}"
	//modApi("me.shedaniel.cloth:cloth-config-fabric:${project.cloth_config_version}") {
	//	exclude(group: "net.fabricmc.fabric-api")
	//}

	include(fabricApi.module("fabric-api-base", project.fabric_version))
	modImplementation include(fabricApi.module("fabric-networking-api-v1", project.fabric_version))
	modImplementation include(fabricApi.module("fabric-screen-api-v1", project.fabric_version))
	modImplementation include(fabricApi.module("fabric-rendering-v1", project.fabric_version))
	modImplementation include(fabricApi.module("fabric-resource-loader-v0", project.fabric_version))
}

processResources {
	inputs.property "version", project.version

	filesMatching("fabric.mod.json") {
		expand "version": project.version
	}
}

tasks.withType(JavaCompile).configureEach {
	it.options.release = 17
}

java {
	// withSourcesJar()
}

task testJar (type: Jar) {
	classifier = 'test'
	from sourceSets.test.output
	testJar.finalizedBy('prepareRemapJar')
	testJar.finalizedBy('remapJar')

	from("LICENSE") {
		// NO-OP
	}
	
	doFirst {
		remapJar.classifier = 'test-reobf'
		remapJar.inputFile = testJar.outputs.files.singleFile
	}
}

jar {

	from("LICENSE") {
		// NO-OP
	}
}

curseforge {

    project {
		println("Pushing CurseGradle specifications for project ID: ${curse_id}")	
	
		// Specified as cmd argument
        apiKey = findProperty('curseKey') ?: 'none'
        
		id = "${curse_id}"
        releaseType = "${curse_release}"
        changelogType = 'html'
        changelog = file('docs/changelog.html')
		mainArtifact(remapJar)
		
		addGameVersion '1.19.2'
		addGameVersion '1.19.1'
		addGameVersion 'Quilt'
		addGameVersion 'Fabric'
		addGameVersion 'Java 17'
		
		relations {
			embeddedLibrary 'fabric-api'
			optionalDependency 'modmenu'
			optionalDependency 'cloth-config'
		}
		
		afterEvaluate {
			uploadTask.dependsOn(remapJar)
		}
		
		//debug = true
        //addArtifact(sourcesJar)
        //addArtifact(apiJar)
    }
	
	options {
		forgeGradleIntegration = false
	}
}

modrinth {
    token = findProperty('modrinthKey') ?: 'none'
    projectId = "no-chat-reports"
    versionNumber = "Fabric-" + project.mod_version
	versionName = "No Chat Reports Fabric-" + project.mod_version
    versionType = "release"
	changelog = rootProject.file("docs/changelog.html").text
    uploadFile = remapJar
    gameVersions = ["1.19.2", "1.19.1"]
	loaders = ['fabric', 'quilt']
	
	dependencies {
		// The scope can be `required`, `optional`, or `incompatible`
		embedded.project "fabric-api"
		optional.project "modmenu"
		optional.project "cloth-config"
    }
	
	//syncBodyFrom = rootProject.file("docs/README.md").text
}

afterEvaluate {
	upload.dependsOn(remapJar)
}

task upload {
	dependsOn('modrinth')
	dependsOn('curseforge')
}