summaryrefslogtreecommitdiffstats
path: root/forge/build.gradle
blob: 2e60b18a6a310684350a8da8f0601bbd1e1a8a73 (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
buildscript {
    repositories {
        mavenCentral()
        maven { url file("deps") }
        maven { url = 'https://maven.minecraftforge.net' }
        maven { url = 'https://dist.creeper.host/Sponge/maven' }
        maven { url 'https://plugins.gradle.org/m2/' }
        maven {
            url = 'https://repo.spongepowered.org/repository/maven-public/'
            content { includeGroup "org.spongepowered" }
        }
		maven {
			name "Gradle Plugin Portal"
			url 'https://plugins.gradle.org/m2/'
			content {
				includeGroup "com.modrinth"
			}
		}
    }
}

plugins {
    id 'java'
    id 'idea'
    id 'eclipse'
    id 'maven-publish'
    id 'net.minecraftforge.gradle' version '[7.0.17,8.0)'
    id "com.modrinth.minotaur" version "2.+"
    id 'net.darkhax.curseforgegradle' version '1.+'
}

println("Specifying project version/group/archivesBaseName...")
version = "${mod_version}"
group = "${maven_group}"

base {
    archivesName = "${archives_base_name}"
}

println("Specifying Java compatibility...")
java.toolchain.languageVersion = JavaLanguageVersion.of(25)

println("Java Installation Data:")
println(" - Java Version: " + System.getProperty('java.version'))
println(" - JVM Version: " + System.getProperty('java.vm.version'))
println(" - Vendor: " + System.getProperty('java.vendor'))
println(" - OS Archetype: " + System.getProperty('os.arch'))

compileJava.options.encoding = "UTF-8"

minecraft {
    mappings channel: 'official', version: minecraft_version

    accessTransformers = files('src/main/resources/META-INF/accesstransformer.cfg')

    runs {
        configureEach {
            workingDir.convention layout.projectDirectory.dir('run')
            systemProperty 'forge.logging.markers', 'REGISTRIES'
            systemProperty 'forge.logging.console.level', 'debug'
            args "--mixin.config=mixins/common/nochatreports.mixins.json"
            args "--mixin.config=mixins/forge/nochatreports-forge.mixins.json"
        }

        register('client') {
            systemProperty 'forge.enabledGameTestNamespaces', mod_id
            systemProperty 'forge.logging.markers', 'SCAN,REGISTRIES,REGISTRYDUMP'
            systemProperty 'forge.logging.console.level', 'debug'
        }

        register('server') {
            systemProperty 'forge.enabledGameTestNamespaces', mod_id
            systemProperty 'forge.logging.markers', 'SCAN,REGISTRIES,REGISTRYDUMP'
            systemProperty 'forge.logging.console.level', 'debug'
            args '--nogui'
        }
    }
}

sourceSets.main.resources {
    // NO-OP
}

repositories {
	println("Specifying repositories...")
	maven {  url file("deps")                             } // local
	maven {  url = "https://maven.theillusivec4.top/"     } // curios
	maven {  url = "https://maven.blamejared.com/"        } // patchouli
	maven {  url = "https://repo.spongepowered.org/maven" } // mixin
	maven {  url "https://maven.shedaniel.me/"            } // cloth config
	minecraft.mavenizer(it)                                 // minecraft
}

dependencies {
	println("Processing dependencies...")	

	// Minecraft & Forge
	implementation minecraft.dependency("net.minecraftforge:forge:$minecraft_version-$forge_version")
	implementation "generic:modmenu:5.0.2"
	implementation "generic:fabric-annotations:v1.0.0"
	implementation "generic:cloth-config-api:14.0.126"
	
	// Hack fix for now, force jopt-simple to be exactly 5.0.4 because Mojang ships that version, but some transtive dependencies request 6.0+ 
    implementation('net.sf.jopt-simple:jopt-simple:5.0.4') { version { strictly '5.0.4' } }
}


jar {
	println("Processing manifest...")	

    manifest {
        attributes([
            "Specification-Title": "${mod_name}",
            "Specification-Vendor": "${mod_author}",
            "Specification-Version": "${version}",
            "Implementation-Title": "${mod_name}",
            "Implementation-Version": "${version}",
            "Implementation-Vendor" :"${mod_author}",
            "Implementation-Timestamp": new Date().format("yyyy-MM-dd'T'HH:mm:ssZ"),
            "MixinConfigs": "mixins/common/nochatreports.mixins.json, mixins/forge/nochatreports-forge.mixins.json"
        ])
    }
}

processResources {
	println("Processing resources...")
	duplicatesStrategy = DuplicatesStrategy.EXCLUDE
	exclude 'META-INF/mods.toml'

    from("${project.projectDir}/docs/META-INF") {
		println("Inflating mods.toml...")	
	
		// Replace properties in mods.toml with ones derived from settings.gradle
        include 'mods.toml'
        expand 'mod_license': mod_license, 
		'mod_version': version, 
		'mod_id' : mod_id, 
		'mod_name': mod_name, 
		'mod_url': mod_url, 
		'mod_author': mod_author, 
		'mod_icon': mod_icon, 
		'mod_description': mod_description,
		'issue_tracker_url': issue_tracker_url,
		'dep_forge': dep_forge,
		'dep_minecraft': dep_minecraft,
		'contributor_0': contributor_0
		into 'META-INF'
    }

    from("${rootProject.projectDir}/docs") {
        include 'CHANGELOG.md'
    }
	
	from("${rootProject.projectDir}") {
        include 'LICENSE'
	}
}

task curseforge(type: net.darkhax.curseforgegradle.TaskPublishCurseForge) {
	println("[Forge] Pushing CurseForgeGradle specifications for project ID: ${curse_id}")
	disableVersionDetection()
	
	apiToken = findProperty('curseKey') ?: '0'
	
	def projectId = project.curse_id
	def mainFile = upload(projectId, jar)
	
	mainFile.changelogType = 'markdown'
	mainFile.changelog = rootProject.file("docs/CHANGELOG.md").text
	mainFile.releaseType = "${version_type}"
	
	mainFile.addModLoader('Forge')
	mainFile.addJavaVersion('Java 25')
	mainFile.addGameVersion(project.minecraft_version)
}

modrinth {
    token = findProperty('modrinthKey') ?: 'none'
    projectId = "no-chat-reports"
    versionNumber = "Forge-" + project.version
	versionName = "No Chat Reports Forge-" + project.version
    versionType = "${version_type}"
	changelog = rootProject.file("docs/CHANGELOG.md").text
    uploadFile = jar
    gameVersions = [ project.minecraft_version ]
	
	syncBodyFrom = rootProject.file("docs/README.md").text
}

task upload {
	dependsOn('modrinth')
	dependsOn('curseforge')
}


task updateResources() {
    // NO-OP
}

tasks.updateResources.dependsOn processResources

//tasks.withType(JavaCompile) {
//    options.failOnError(true)
//}

//jar.finalizedBy('reobfJar') 
//publish.dependsOn('reobfJar')

publishing {

    publications {
        mavenJava(MavenPublication) {
            artifact jar
        }
    }
    repositories {
        maven {
            url file("mcmodsrepo")
        }
    }
}

sourceSets.each {
    def dir = layout.buildDirectory.dir("sourceSets/$it.name")
    it.output.resourcesDir = dir
    it.java.destinationDirectory = dir
}